---

发件人： Michael Anstis <michael.anstis@gmail.com>
收件人： Rules Users List <rules-users@lists.jboss.org>
发送日期： 2011/3/19 (周六) 12:25:48 上午
主 题： Re: [rules-users] how to ensure that one rule only is executed once?

You'd need to make sure you inform the engine that Order's price has changed:-

when
    ...
then
    modify( $o ) {
        setPrice( $o.getPrice() - 20);
    }

You could also consider using agenda-groups or lock-on-active to provide your behaviour.

agenda-groups

rule "rule 1"
//implied default agenda-group of MAIN
when
    $o : Order (amount>100 && <200);
then
    modify( $o ) {
        setPrice( $o.getPrice() - 10);
    }
    drools.setFocus("next step in calculation");
end

rule "rule 2"
//implied default agenda-group of MAIN
when
    $o:Order (amount>200);
then
    modify( $o ) {
        setPrice($o.getPrice() - 20);
    }
    drools.setFocus("next step in calculation");
end

rule "rule 3"
agenda-group "next step in calculation"
when
    $o : Order(....)
then
    ....
end

lock-on-active

rule "rule 1"
//implied default agenda-group of MAIN
lock-on-active true
when
    $o : Order (amount>100 && <200);
then
    modify( $o ) {
        setPrice( $o.getPrice() - 10);
    }
end

rule "rule 2"
//implied default agenda-group of MAIN
lock-on-active true
when
    $o:Order (amount>200);
then
    modify( $o ) {
        setPrice($o.getPrice() - 20);
    }
end

rule "rule 3"
agenda-group "next step in calculation"
when
    $o : Order(....)
then
    ....
end